ESP-NOW入门（基于ESP32）

这篇文章将带领大家来了解如何使用ESP-NOW，文章内容来源于国外网站，我认为这篇文章比较有价值，这是基于ESP32板之间交换数据的一种协议，当然也支持ESP8266。ESP-NOW是乐鑫开发的无连接通信协议，具有短数据包传输的功能。该协议使多个设备可以轻松地相互通信。

材料准备

1. ESP32模块至少两个
2. 搭建好了ESP32环境的arduino IDE，或者使用notes.qutaojiao.com中的在线编译环境

介绍ESP-NOW

ESP-NOW是Espressif开发的一种协议，在Espressif网站上表示，它使多个设备无需使用Wi-Fi即可相互通信。该协议类似于低功率的2.4GHz无线连接（…）。设备之间需要进行配对，然后才能进行通信。配对完成后，连接安全且点对点，无需握手。”

这意味着在将设备彼此配对后，连接将保持不变。换句话说，如果您的一块板突然断电或复位，则在重新启动时，它将自动连接到其对等端以继续通信。

ESP-NOW支持以下功能：

• 加密和未加密的单播通信；
• 混合加密和未加密对等设备；
• 最多可以承载250字节有效负载；
• 发送回调函数，可以设置为通知应用层
  传输成功或失败。

ESP-NOW技术还具有以下限制：

• 有限的加密对等体。工作站模式下最多支持10个加密对等体；在SoftAP或SoftAP + Station模式下最多6个；
• 支持多个未加密的对等方，但是它们的总数应少于20，其中包括已加密的对等方；
• 有效负载限制为250个字节。

简而言之，ESP-NOW是一种快速通信协议，可用于在ESP32板之间交换小消息（最大250字节）。

ESP-NOW具有多种用途，您可以在不同的设置中进行单向或双向通信。

ESP-NOW单向通信

例如，在单向通信中，您可能会遇到以下情形：

• 一个ESP32开发板向另一个ESP32开发板发送数据

这种配置非常容易实现，并且很容易将数据从一块板发送到另一块板，例如传感器读数或控制GPIO的ON和OFF命令。

• 一个“主” ESP32将数据发送到多个ESP32“从站”

一块ESP32板向不同的ESP32板发送相同或不同的命令。此配置是构建遥控器之类的理想选择。整个房屋中可以有几块ESP32板，它们由一块主ESP32板控制。

• 一个ESP32“从站”从多个“主站”接收数据

如果要将多个传感器节点的数据收集到一个ESP32板上，则此配置非常理想。例如，可以将其配置为Web服务器以显示来自所有其他板的数据。

ESP32：获取板的MAC地址

要通过ESP-NOW进行通信，您需要知道ESP32接收器的MAC地址。这样您便知道将信息发送到哪个设备。

每个ESP32都有一个唯一的MAC地址，这就是我们确定每个板使用ESP-NOW向其发送数据的方式（了解如何获取和更改ESP32 MAC地址）。

要获取主板的MAC地址，请上传以下代码。

#include "WiFi.h"
 
void setup(){
  Serial.begin(115200);
  WiFi.mode(WIFI_MODE_STA);
  Serial.println(WiFi.macAddress());
}
 
void loop(){

}

上传代码后，以115200的波特率打开串口监视器，然后按ESP32 RST / EN按钮。MAC地址应如下打印：

保存您的板子MAC地址，因为您需要它通过ESP-NOW将数据发送到正确的板上。

ESP-NOW单向点对点通信

要通过ESP-NOW进行通信，您需要知道ESP32接收器的MAC地址。这样您便知道将信息发送到哪个设备。

每个ESP32都有一个唯一的MAC地址，这就是我们确定每个板使用ESP-NOW向其发送数据的方式（了解如何获取和更改ESP32 MAC地址）。

要获取主板的MAC地址，请上传以下代码：

#include "WiFi.h"
 
void setup(){
  Serial.begin(115200);
  WiFi.mode(WIFI_MODE_STA);
  Serial.println(WiFi.macAddress());
}
 
void loop(){

}

上传代码后，以115200的波特率打开串口监视器，然后按ESP32 RST / EN按钮。MAC地址应如下打印：

保存您的板MAC地址，因为您需要它通过ESP-NOW将数据发送到正确的板上。

ESP-NOW单向点对点通信

为了让您开始使用ESP-NOW无线通信，我们将构建一个简单的项目，展示如何从一个ESP32向另一个ESP32发送消息。一个ESP32将成为“发送方”，另一个ESP32将成为“接收方”。

我们将发送一个结构，其中包含char，int，float，String和boolean类型的变量。然后，您可以修改结构以发送适合您项目的任何变量类型（例如传感器读数或布尔变量以打开或关闭某些内容）。

为了更好地理解，我们将ESP32＃1称为“发送者”，将ESP32＃2称为“接收者”。

这是我们应该包含在发送者程序中的内容：

1. 初始化ESP-NOW;
2. 在发送数据时注册回调函数– OnDataSent发送消息时将执行功能。这可以告诉我们消息是否成功发送；
3. 添加对等设备（接收方）。为此，您需要知道接收者的MAC地址；
4. 向对等设备发送消息。

在接收者，程序应包括：

1. 初始化ESP-NOW;
2. 注册接收回调函数（OnDataRecv）。收到消息后将执行的功能。
3. 在该回调函数内部，将消息保存到变量中以执行具有该信息的任何任务。

ESP-NOW与设备接收消息或发送消息时调用的回调函数一起使用（您可以确定消息是否已成功发送或失败）。

ESP-NOW有用的功能

以下是最基本的ESP-NOW功能的摘要：

ESP32发送板程序（ESP-NOW）

这是ESP32发送板的代码。将代码复制到您的Arduino IDE，但尚未上传。您需要进行一些修改以使其适合您：

#include <esp_now.h>
#include <WiFi.h>

// REPLACE WITH YOUR RECEIVER MAC Address
uint8_t broadcastAddress[] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};

// Structure example to send data
// Must match the receiver structure
typedef struct struct_message {
  char a[32];
  int b;
  float c;
  String d;
  bool e;
} struct_message;

// Create a struct_message called myData
struct_message myData;

// callback when data is sent
void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  Serial.print("rnLast Packet Send Status:t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}
 
void setup() {
  // Init Serial Monitor
  Serial.begin(115200);
 
  // Set device as a Wi-Fi Station
  WiFi.mode(WIFI_STA);

  // Init ESP-NOW
  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }

  // Once ESPNow is successfully Init, we will register for Send CB to
  // get the status of Trasnmitted packet
  esp_now_register_send_cb(OnDataSent);
  
  // Register peer
  esp_now_peer_info_t peerInfo;
  memcpy(peerInfo.peer_addr, broadcastAddress, 6);
  peerInfo.channel = 0;  
  peerInfo.encrypt = false;
  
  // Add peer        
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
}
 
void loop() {
  // Set values to send
  strcpy(myData.a, "THIS IS A CHAR");
  myData.b = random(1,20);
  myData.c = 1.2;
  myData.d = "Hello";
  myData.e = false;

  // Send message via ESP-NOW
  esp_err_t result = esp_now_send(broadcastAddress, (uint8_t *) &myData, sizeof(myData));
   
  if (result == ESP_OK) {
    Serial.println("Sent with success");
  }
  else {
    Serial.println("Error sending the data");
  }
  delay(2000);
}

代码如何工作

首先，包括 esp_now.h 和 WiFi.h 库。

#include <esp_now.h>
#include <WiFi.h>

在下一行中，应插入ESP32接收器MAC地址。

uint8_t broadcastAddress[] = {0x30, 0xAE, 0xA4, 0x07, 0x0D, 0x64};

在我们的例子中，接收者的MAC地址是： 30：AE：A4：07：0D：64，但您需要用自己的MAC地址替换该变量。

然后，创建一个包含我们要发送的数据类型的结构。我们称这种结构struct_message它包含5种不同的变量类型。您可以更改它以发送所需的任何变量类型。

typedef struct struct_message {
  char a[32];
  int b;
  float c;
  String d;
  bool e;
} struct_message;

然后，创建一个新的类型为 struct_message 它被称作 myData 将存储变量值。

struct_message myData;

接下来，定义 OnDataSent()功能。这是一个回调函数，将在发送消息时执行。在这种情况下，此功能仅打印是否成功发送了邮件。

void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  Serial.print("rnLast Packet Send Status:t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}

在里面 setup()，初始化串行监视器以进行调试：

Serial.begin(115200);

将设备设置为Wi-Fi站点：

WiFi.mode(WIFI_STA);

立即初始化ESP：

if (esp_now_init() != ESP_OK) {
  Serial.println("Error initializing ESP-NOW");
  return;
}

成功初始化ESP-NOW之后，注册将在发送消息时调用的回调函数。在这种情况下，我们注册OnDataSent（） 先前创建的功能。

esp_now_register_send_cb(OnDataSent);

之后，我们需要与另一个ESP-NOW设备配对以发送数据。这就是我们在接下来的几行中所做的：

//Register peer
esp_now_peer_info_t peerInfo;
memcpy(peerInfo.peer_addr, broadcastAddress, 6);
peerInfo.channel = 0;
peerInfo.encrypt = false;

//Add peer
if (esp_now_add_peer(&peerInfo) != ESP_OK){
  Serial.println("Failed to add peer");
  return;
}

在loop()

我们将每2秒通过ESP-NOW发送一条消息（您可以更改此延迟时间）。

首先，我们将变量值设置如下：

strcpy(myData.a, "THIS IS A CHAR");
myData.b = random(1,20);
myData.c = 1.2;
myData.d = "Hello";
myData.e = false;

请记住 myData是一个结构。在这里，我们分配要在结构内部发送的值。例如，第一行分配一个char，第二行分配一个随机的Int数，一个Float，一个String和一个Boolean变量。

我们创建这种结构来向您展示如何发送最常见的变量类型。您可以更改结构以发送任何其他类型的数据。

最后，发送消息如下：

esp_err_t result = esp_now_send(broadcastAddress, (uint8_t *) &myData, sizeof(myData));

检查消息是否已成功发送：

if (result == ESP_OK) {
  Serial.println("Sent with success");
}
else {
  Serial.println("Error sending the data");
}

这 loop()每2000毫秒（2秒）执行一次。

delay(2000);

ESP32接收板程序（ESP-NOW）

将以下代码上传至ESP32接收板:

代码如何工作

与发送板类似，首先包括以下库：

#include <esp_now.h>
#include <WiFi.h>

创建一个结构以接收数据。此结构应与发件板程序中定义的结构相同。

typedef struct struct_message {
  char a[32];
  int b;
  float c;
  String d;
  bool e;
} struct_message;

创建一个 struct_message 变量称为 myData。

创建一个回调函数，当ESP32通过ESP-NOW接收数据时将调用该函数。该函数称为onDataRecv（） 并应接受以下几个参数：

void OnDataRecv(const uint8_t * mac, const uint8_t *incomingData, int len) {

我们复制内容 入库数据 数据变量放入 myData 多变的。

memcpy(&myData, incomingData, sizeof(myData));

现在 myData结构内部包含几个变量，以及发送方ESP32发送的值。访问变量一种，例如，我们只需要致电 myData.a。

在此示例中，我们仅打印接收到的数据，但是在实际应用中，例如，您可以在显示器上打印数据。

  Serial.print("Bytes received: ");
  Serial.println(len);
  Serial.print("Char: ");
  Serial.println(myData.a);
  Serial.print("Int: ");
  Serial.println(myData.b);
  Serial.print("Float: ");
  Serial.println(myData.c);
  Serial.print("String: ");
  Serial.println(myData.d);
  Serial.print("Bool: ");
  Serial.println(myData.e);
  Serial.println();
}

在里面 setup（），初始化串行监视器。

Serial.begin(115200);

将设备设置为Wi-Fi站。

WiFi.mode(WIFI_STA);

立即初始化ESP：

if (esp_now_init() != ESP_OK) {
  Serial.println("Error initializing ESP-NOW");
  return;
}

注册接收数据时将调用的回调函数。在这种情况下，我们注册OnDataRecv（） 先前创建的功能。

esp_now_register_recv_cb(OnDataRecv);

测试ESP-NOW通信

将发送板程序上传到发送者ESP32板，将接收板程序上传到接收者ESP32板。

现在，打开两个Arduino IDE窗口。一个给接收者，另一个给发送者。打开每个板卡的串行监视器。每个板应该是不同的COM端口。

这就是您在发送板获得的消息：

这就是您应该在接收板端得到的。请注意，Int变量会在每次接收到的读数之间变化（因为我们在发送方将其设置为随机数）：

我们测试了两块板之间的通信范围，并且能够在空旷的地方进行长达220米（约722英尺）的稳定通信。在该实验中，两个ESP32天线都指向彼此。

最后

我们试图使示例尽可能简单，以便更好地理解一切。还有更多与ESP-NOW相关的功能在您的项目中很有用，例如：管理对等点，删除对等点，扫描从设备等…有关完整的示例，请在Arduino IDE中转到“文件” >“示例” >“ ESP32”> ESPNow，然后选择示例程序之一。

文中如果有错误或者任何问题，欢迎大家下方留言。