Arduino内置教程-字符串-字符串追加运算符

简介

• 就像你可以用StringAdditionOperator把字符串和其他数据对象连到一起一样，你也可以用 += 运算符和 concat() 命令来在字符串后面加其他东西。 += 运算符和 concat() 命令用同一种方式工作，随便你想选哪一种方式。下面两个例子说明这两种方法，并且得出同一个字符串：

String stringOne = "A long integer: ";    
// using += to add a long variable to a string:   
stringOne += 123456789; 

• 或者

String stringTwo = "A long integer: ";    
// using concat() to add a long variable to a string:   
stringTwo.concat(123456789); 

• 在这两种情况下，stringOne等于 “A long integer: 123456789″。就像+运算符，这些运算符对于往数据组合对象里增加长字符串很方便。

硬件要求

• Arduino or Genuino开发板

电路

• 这个例子没有额外的电路连接，除了你的开发板需要连接到你的电脑，并且打开Arduino IDE的串口监视器窗口。

样例代码

String stringOne, stringTwo;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  stringOne = String("Sensor ");
  stringTwo = String("value");
  // send an intro:
  Serial.println("\n\nAppending to a string:");
  Serial.println();
}

void loop() {
  Serial.println(stringOne);  // prints  "Sensor "

  // adding a string to a string:
  stringOne += stringTwo;
  Serial.println(stringOne);  // prints "Sensor value"

  // adding a constant string to a string:
  stringOne += " for input ";
  Serial.println(stringOne);  // prints "Sensor value for input"

  // adding a constant character to a string:
  stringOne += 'A';
  Serial.println(stringOne);   // prints "Sensor value for input A"

  // adding a constant integer to a string:
  stringOne += 0;
  Serial.println(stringOne);   // prints "Sensor value for input A0"

  // adding a constant string to a string:
  stringOne += ": ";
  Serial.println(stringOne);  // prints "Sensor value for input"

  // adding a variable integer to a string:
  stringOne += analogRead(A0);
  Serial.println(stringOne);   // prints "Sensor value for input A0: 456" or whatever analogRead(A0) is

  Serial.println("\n\nchanging the Strings' values");
  stringOne = "A long integer: ";
  stringTwo = "The millis(): ";

  // adding a constant long integer to a string:
  stringOne += 123456789;
  Serial.println(stringOne);   // prints "A long integer: 123456789"

  // using concat() to add a long variable to a string:
  stringTwo.concat(millis());
  Serial.println(stringTwo); // prints "The millis(): 43534" or whatever the value of the millis() is

  // do nothing while true:
  while (true);
}